De afgelopen maanden zijn er veel Windows(10) updates geweest. Deze updates beïnvloeden het zoeken in Microsoft Outlook negatief. Het gaat om de volgende updates:
- najaar 2015: KB3114409 (deze update is inmiddels teruggedraaid)
- mei 2017 meerdere KB’s
- najaar 2017 Windows Update 1709
Symptomen van het probleem:
- Langzame zoekresultaten
- Resultaten worden niet gevonden
In Outlook 2013 en 2016 is dit relatief gemakkelijk op te lossen. In Outlook 2010 is het wat ingewikkelder. Hieronder een script waarmee het probleem opgelost wordt.
Controleer de volgende stappen voor het uitvoeren van de scripts:
- Office 2010: installeer SP2 (https://www.microsoft.com/nl-nl/download/details.aspx?id=39667)
- Controleer op de laatste Windows updates
- Voor het starten van de scripts Microsoft Outlook en alle (office) programma’s eerst sluiten.
Microsoft Outlook 2010
RepairOutlook14Search.cmd
Script om uit te voeren. Het script bevat de volgende stappen:
- Variablen, eventueel aan te passen bij subversies of 64 BIT
- Aanvraag van Administrator bevoegdheden: Klik op ja
- Opslaan van productcode in o14productkey.txt
- DisableBackOff aanpassing in register (met behulp van Microsoft tool)
- Cleanup van Windows search
- Herstel van Office 2010 software via MSI
- (Office 2010 x86 en x64 NL en EN MSI images heb ik online staan en zijn op aanvraag beschikbaar)
@ECHO OFF
ECHO author : Arjan Lobbezoo, IT professional & consultant
ECHO email : info@solideautomatisering.nl
ECHO file : RepairOutlook14Search.cmd
ECHO description : Repair and boost Microsoft Outlook 2010 (Office 14) search index after W10 updates
ECHO dependencies : SubInAcl from: https://www.microsoft.com/en-us/download/details.aspx?id=23510
ECHO ospp.vbs included in Office 2010 program files
ECHO getkey.vbs included in zip (arjanlobbezoo.nl)
ECHO Indexing-Fast.reg included in zip (arjanlobbezoo.nl)
REM // Set variables
SET officelocation=C:\Program Files (x86)\Microsoft Office\Office14
SET officeguid={90140000-003D-0000-0000-0000000FF1CE}
if _%1_==_payload_ goto :payload
:requestadmin
set vbs=%temp%\requestadmin.vbs
echo Set UAC = CreateObject^("Shell.Application"^) >> "%vbs%"
echo UAC.ShellExecute "%~s0", "payload %~sdp0 %*", "", "runas", 1 >> "%vbs%"
"%temp%\requestadmin.vbs"
del "%temp%\requestadmin.vbs"
goto :eof
:payload
cd /d %2
shift
shift
REM // Save office key to log file o14productkey
REM // https://jacobsalmela.com/2015/02/26/find-your-windows-product-key-without-any-software/
if not exist "o14productkey.txt" (
cscript "%officelocation%\ospp.vbs" /dstatus > o14productkey.txt
cscript getkey.vbs >> o14productkey.txt
)
REM // Enable DisableBackOff for fast indexing
REM // https://office-watch.com/2016/force-windows-indexing-to-run-faster/
subinacl /subkeyreg "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Search\Gathering Manager" /setowner=administrators
subinacl /keyreg "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Search\Gathering Manager" /setowner=administrators /grant=administrators=f
Regedit /S Indexing-Fast.reg
REM // Cleanup Windows Search
Net Stop Wsearch
Net Stop Wsearch
del "%programdata%\microsoft\search\data\applications\windows\Windows.edb.bak"
move "%programdata%\microsoft\search\data\applications\windows\Windows.edb" "%programdata%\microsoft\search\data\applications\windows\Windows.edb.bak"
Net Start Wsearch
Net Start Wsearch
Net Start Wsearch
REM // Repair office14
msiexec /f %officeguid%
goto :eof
:eof
Voor het het script van Outlook 2010 zijn een aantal afhankelijkheden nodig. Deze staan hieronder:
Indexing-Fast.reg
Zorgt ervoor dat indexering altijd doorgaat ook als de computer gebruikt wordt. Kost iets meer CPU tijdens gebruik maar zorgt wel voor consistentie.
Windows Registry Editor Version 5.00 [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Search\Gathering Manager] "DisableBackOff"=dword:00000001
getkey.vbs
Uitlezen van de productkey (die ook in het doosje staat). Ik heb dit onderdeel toegevoegd voor het geval dat de MSI repair mislukt en de product key nodig is bij een legitieme (!) installatie. Office 2010 x86 en x64 NL en EN MSI images heb ik online staan en zijn op aanvraag beschikbaar.
Set WshShell = CreateObject("WScript.Shell")
OfficeLocation = "C:\Program Files (x86)\Microsoft Office\Office14\"
Set fso = CreateObject ("Scripting.FileSystemObject")
Set stdout = fso.GetStandardStream (1)
Set stderr = fso.GetStandardStream (2)
'stdout.WriteLine "This will go to standard output."
'stderr.WriteLine "This will go to error output."
stdout.WriteLine ConvertToKey(WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Office\14.0\Registration\{90140000-003D-0000-0000-0000000FF1CE}\DigitalProductId"))
'64bit? "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Office\14.0\Registration\{90140000-003D-0000-1000-0000000FF1CE}\DigitalProductId"
Function ConvertToKey(Key)
Const KeyOffset = 808 'offset for Office 2010
i = 28
Chars = "BCDFGHJKMPQRTVWXY2346789"
Do
Cur = 0
x = 14
Do
Cur = Cur * 256
Cur = Key(x + KeyOffset) + Cur
Key(x + KeyOffset) = (Cur \ 24) And 255
Cur = Cur Mod 24
x = x -1
Loop While x >= 0
i = i -1
KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
If (((29 - i) Mod 6) = 0) And (i <> -1) Then
i = i -1
KeyOutput = "-" & KeyOutput
End If
Loop While i >= 0
ConvertToKey = KeyOutput
End Function
Microsoft Outlook 2013 en 2016
RepairOutlook15and16Search.cmd
In dit script wordt uitsluitend de Windows Search functionaliteit gereset om er voor te zorgen dat de indexering weer werkt.
@ECHO OFF
ECHO author : Arjan Lobbezoo, IT professional & consultant
ECHO email : info@solideautomatisering.nl
ECHO file : RepairOutlook15and16Search.cmd
ECHO description : Repair Microsoft Outlook 2013/2016 (Office 15/16) search index after W10 updates
if _%1_==_payload_ goto :payload
:requestadmin
set vbs=%temp%\requestadmin.vbs
echo Set UAC = CreateObject^("Shell.Application"^) >> "%vbs%"
echo UAC.ShellExecute "%~s0", "payload %~sdp0 %*", "", "runas", 1 >> "%vbs%"
"%temp%\requestadmin.vbs"
del "%temp%\requestadmin.vbs"
goto :eof
:payload
cd /d %2
shift
shift
REM // Cleanup Windows Search and check indexing options
Net Stop Wsearch
Net Stop Wsearch
del "%programdata%\microsoft\search\data\applications\windows\Windows.edb.bak"
move "%programdata%\microsoft\search\data\applications\windows\Windows.edb" "%programdata%\microsoft\search\data\applications\windows\Windows.edb.bak"
Net Start Wsearch
Net Start Wsearch
Net Start Wsearch
control.exe srchadmin.dll
:eof
